<declaración> -> <especificadores de declaración> <lista de declaradores>?

<especificadores de declaración> -> <especificador de clase de almacenamiento> <especificadores de declaración>?|

<especificador de tipo> <especificadores de declaración>? |

<calificador de tipo> <especificadores de declaración>?

<lista de declaradores> -> <declarador> |

<lista de declaradores> , <declarador>

<declarador> -> <decla> |

<decla> = <inicializador>

<inicializador> -> <expresión de asignación> |

/\* Inicialización de tipos escalares \*/ {<lista de inicializadores>} |

/\* Inicialización de tipos estructurados \*/ {<lista de inicializadores> , }

<lista de inicializadores> -> <inicializador> |

<lista de inicializadores> , <inicializador>

<especificador de clase de almacenamiento> -> uno de typedef static auto register extern

***No más de un especificador de clase de almacenamiento> puede haber en una declaración***

<especificador de tipo> -> uno de void char short int long float double signed unsigned <especificador de "struct" o "union"> <especificador de "enum"> <nombre de "typedef">

<calificador de tipo> -> const | volatile

<especificador de "struct" o "union"> -> <"struct" o "union"> <identificador>? {<lista de declaraciones "struct">} | <"struct" o "union"> <identificador>

<"struct" o "union"> -> struct | union

<lista de declaraciones "struct"> -> <declaración "struct"> |

<lista de declaraciones "struct"> <declaración "struct">

<declaración "struct"> -> <lista de calificadores> <declaradores "struct"> ;

<lista de calificadores> -> <especificador de tipo> <lista de calificadores>? |

<calificador de tipo> <lista de calificadores>?

<declaradores "struct"> -> <decla "struct"> |

<declaradores "struct"> , <decla "struct">

<decla "struct"> -> <decla> | <decla>? : <expresión constante>

<decla> -> <puntero>? <declarador directo>

<puntero> -> \* <lista calificadores tipos>? | \* <lista calificadores tipos>? <puntero>

<lista calificadores tipos> -> <calificador de tipo> | <lista calificadores tipos> <calificador de tipo>

<declarador directo> -> <identificador> |

( <decla> ) |

<declarador directo> [ <expresión constante>? ] |

<declarador directo> ( <lista tipos parámetros> ) /\* Declarador nuevo estilo \*/ <declarador directo> ( <lista de identificadores>? ) /\* Declarador estilo obsoleto \*/

<lista tipos parámetros> -> <lista de parámetros> |

<lista de parámetros> , . . .

<lista de parámetros> -> <declaración de parámetro> | <lista de parámetros> , <declaración de parámetro>

<declaración de parámetro> -> <especificadores de declaración> <decla>

| /\* Parámetros "nombrados" \*/ <especificadores de declaración> <declarador abstracto>? /\* Parámetros "anónimos" \*/

<lista de identificadores> -> <identificador> | <lista de identificadores> , <identificador>

<especificador de "enum"> -> enum <identificador>? { <lista de enumeradores> } | enum <identificador>

<lista de enumeradores> -> <enumerador> | <lista de enumeradores> , <enumerador>

<enumerador> -> <constante de enumeración> | <constante de enumeración> = <expresión constante>

<constante de enumeración> -> <identificador>

<nombre de "typedef"> -> <identificador>

<nombre de tipo> -> <lista de calificadores> <declarador abstracto>?

<declarador abstracto> -> <puntero> | <puntero>? <declarador abstracto directo>

<declarador abstracto directo> -> ( <declarador abstracto> ) |

<declarador abstracto directo>? [ <expresión constante>? ] |

<declarador abstracto directo>? ( <lista tipos parámetros>? )